<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package Test2::API::Instance;
use strict;
use warnings;

our $VERSION = '1.302194';

our @CARP_NOT = qw/Test2::API Test2::API::Instance Test2::IPC::Driver Test2::Formatter/;
use Carp qw/confess carp/;
use Scalar::Util qw/reftype/;

use Test2::Util qw/get_tid USE_THREADS CAN_FORK pkg_to_file try CAN_SIGSYS/;

use Test2::EventFacet::Trace();
use Test2::API::Stack();

use Test2::Util::HashBase qw{
    _pid _tid
    no_wait
    finalized loaded
    ipc stack formatter
    contexts

    add_uuid_via

    -preload

    ipc_disabled
    ipc_polling
    ipc_drivers
    ipc_timeout
    formatters

    exit_callbacks
    post_load_callbacks
    context_acquire_callbacks
    context_init_callbacks
    context_release_callbacks
    pre_subtest_callbacks
};

sub DEFAULT_IPC_TIMEOUT() { 30 }

sub pid { $_[0]-&gt;{+_PID} }
sub tid { $_[0]-&gt;{+_TID} }

# Wrap around the getters that should call _finalize.
BEGIN {
    for my $finalizer (IPC, FORMATTER) {
        my $orig = __PACKAGE__-&gt;can($finalizer);
        my $new  = sub {
            my $self = shift;
            $self-&gt;_finalize unless $self-&gt;{+FINALIZED};
            $self-&gt;$orig;
        };

        no strict 'refs';
        no warnings 'redefine';
        *{$finalizer} = $new;
    }
}

sub has_ipc { !!$_[0]-&gt;{+IPC} }

sub import {
    my $class = shift;
    return unless @_;
    my ($ref) = @_;
    $$ref = $class-&gt;new;
}

sub init { $_[0]-&gt;reset }

sub start_preload {
    my $self = shift;

    confess "preload cannot be started, Test2::API has already been initialized"
        if $self-&gt;{+FINALIZED} || $self-&gt;{+LOADED};

    return $self-&gt;{+PRELOAD} = 1;
}

sub stop_preload {
    my $self = shift;

    return 0 unless $self-&gt;{+PRELOAD};
    $self-&gt;{+PRELOAD} = 0;

    $self-&gt;post_preload_reset();

    return 1;
}

sub post_preload_reset {
    my $self = shift;

    delete $self-&gt;{+_PID};
    delete $self-&gt;{+_TID};

    $self-&gt;{+ADD_UUID_VIA} = undef unless exists $self-&gt;{+ADD_UUID_VIA};

    $self-&gt;{+CONTEXTS} = {};

    $self-&gt;{+FORMATTERS} = [];

    $self-&gt;{+FINALIZED} = undef;
    $self-&gt;{+IPC}       = undef;
    $self-&gt;{+IPC_DISABLED} = $ENV{T2_NO_IPC} ? 1 : 0;

    $self-&gt;{+IPC_TIMEOUT} = DEFAULT_IPC_TIMEOUT() unless defined $self-&gt;{+IPC_TIMEOUT};

    $self-&gt;{+LOADED} = 0;

    $self-&gt;{+STACK} ||= Test2::API::Stack-&gt;new;
}

sub reset {
    my $self = shift;

    delete $self-&gt;{+_PID};
    delete $self-&gt;{+_TID};

    $self-&gt;{+ADD_UUID_VIA} = undef;

    $self-&gt;{+CONTEXTS} = {};

    $self-&gt;{+IPC_DRIVERS} = [];
    $self-&gt;{+IPC_POLLING} = undef;

    $self-&gt;{+FORMATTERS} = [];
    $self-&gt;{+FORMATTER}  = undef;

    $self-&gt;{+FINALIZED}    = undef;
    $self-&gt;{+IPC}          = undef;
    $self-&gt;{+IPC_DISABLED} = $ENV{T2_NO_IPC} ? 1 : 0;

    $self-&gt;{+IPC_TIMEOUT} = DEFAULT_IPC_TIMEOUT() unless defined $self-&gt;{+IPC_TIMEOUT};

    $self-&gt;{+NO_WAIT} = 0;
    $self-&gt;{+LOADED}  = 0;

    $self-&gt;{+EXIT_CALLBACKS}            = [];
    $self-&gt;{+POST_LOAD_CALLBACKS}       = [];
    $self-&gt;{+CONTEXT_ACQUIRE_CALLBACKS} = [];
    $self-&gt;{+CONTEXT_INIT_CALLBACKS}    = [];
    $self-&gt;{+CONTEXT_RELEASE_CALLBACKS} = [];
    $self-&gt;{+PRE_SUBTEST_CALLBACKS}     = [];

    $self-&gt;{+STACK} = Test2::API::Stack-&gt;new;
}

sub _finalize {
    my $self = shift;
    my ($caller) = @_;
    $caller ||= [caller(1)];

    confess "Attempt to initialize Test2::API during preload"
        if $self-&gt;{+PRELOAD};

    $self-&gt;{+FINALIZED} = $caller;

    $self-&gt;{+_PID} = $$        unless defined $self-&gt;{+_PID};
    $self-&gt;{+_TID} = get_tid() unless defined $self-&gt;{+_TID};

    unless ($self-&gt;{+FORMATTER}) {
        my ($formatter, $source);
        if ($ENV{T2_FORMATTER}) {
            $source = "set by the 'T2_FORMATTER' environment variable";

            if ($ENV{T2_FORMATTER} =~ m/^(\+)?(.*)$/) {
                $formatter = $1 ? $2 : "Test2::Formatter::$2"
            }
            else {
                $formatter = '';
            }
        }
        elsif (@{$self-&gt;{+FORMATTERS}}) {
            ($formatter) = @{$self-&gt;{+FORMATTERS}};
            $source = "Most recently added";
        }
        else {
            $formatter = 'Test2::Formatter::TAP';
            $source    = 'default formatter';
        }

        unless (ref($formatter) || $formatter-&gt;can('write')) {
            my $file = pkg_to_file($formatter);
            my ($ok, $err) = try { require $file };
            unless ($ok) {
                my $line   = "* COULD NOT LOAD FORMATTER '$formatter' ($source) *";
                my $border = '*' x length($line);
                die "\n\n  $border\n  $line\n  $border\n\n$err";
            }
        }

        $self-&gt;{+FORMATTER} = $formatter;
    }

    # Turn on IPC if threads are on, drivers are registered, or the Test2::IPC
    # module is loaded.
    return if $self-&gt;{+IPC_DISABLED};
    return unless USE_THREADS || $INC{'Test2/IPC.pm'} || @{$self-&gt;{+IPC_DRIVERS}};

    # Turn on polling by default, people expect it.
    $self-&gt;enable_ipc_polling;

    unless (@{$self-&gt;{+IPC_DRIVERS}}) {
        my ($ok, $error) = try { require Test2::IPC::Driver::Files };
        die $error unless $ok;
        push @{$self-&gt;{+IPC_DRIVERS}} =&gt; 'Test2::IPC::Driver::Files';
    }

    for my $driver (@{$self-&gt;{+IPC_DRIVERS}}) {
        next unless $driver-&gt;can('is_viable') &amp;&amp; $driver-&gt;is_viable;
        $self-&gt;{+IPC} = $driver-&gt;new or next;
        return;
    }

    die "IPC has been requested, but no viable drivers were found. Aborting...\n";
}

sub formatter_set { $_[0]-&gt;{+FORMATTER} ? 1 : 0 }

sub add_formatter {
    my $self = shift;
    my ($formatter) = @_;
    unshift @{$self-&gt;{+FORMATTERS}} =&gt; $formatter;

    return unless $self-&gt;{+FINALIZED};

    # Why is the @CARP_NOT entry not enough?
    local %Carp::Internal = %Carp::Internal;
    $Carp::Internal{'Test2::Formatter'} = 1;

    carp "Formatter $formatter loaded too late to be used as the global formatter";
}

sub add_context_acquire_callback {
    my $self =  shift;
    my ($code) = @_;

    my $rtype = reftype($code) || "";

    confess "Context-acquire callbacks must be coderefs"
        unless $code &amp;&amp; $rtype eq 'CODE';

    push @{$self-&gt;{+CONTEXT_ACQUIRE_CALLBACKS}} =&gt; $code;
}

sub add_context_init_callback {
    my $self =  shift;
    my ($code) = @_;

    my $rtype = reftype($code) || "";

    confess "Context-init callbacks must be coderefs"
        unless $code &amp;&amp; $rtype eq 'CODE';

    push @{$self-&gt;{+CONTEXT_INIT_CALLBACKS}} =&gt; $code;
}

sub add_context_release_callback {
    my $self =  shift;
    my ($code) = @_;

    my $rtype = reftype($code) || "";

    confess "Context-release callbacks must be coderefs"
        unless $code &amp;&amp; $rtype eq 'CODE';

    push @{$self-&gt;{+CONTEXT_RELEASE_CALLBACKS}} =&gt; $code;
}

sub add_post_load_callback {
    my $self = shift;
    my ($code) = @_;

    my $rtype = reftype($code) || "";

    confess "Post-load callbacks must be coderefs"
        unless $code &amp;&amp; $rtype eq 'CODE';

    push @{$self-&gt;{+POST_LOAD_CALLBACKS}} =&gt; $code;
    $code-&gt;() if $self-&gt;{+LOADED};
}

sub add_pre_subtest_callback {
    my $self =  shift;
    my ($code) = @_;

    my $rtype = reftype($code) || "";

    confess "Pre-subtest callbacks must be coderefs"
        unless $code &amp;&amp; $rtype eq 'CODE';

    push @{$self-&gt;{+PRE_SUBTEST_CALLBACKS}} =&gt; $code;
}

sub load {
    my $self = shift;
    unless ($self-&gt;{+LOADED}) {
        confess "Attempt to initialize Test2::API during preload"
            if $self-&gt;{+PRELOAD};

        $self-&gt;{+_PID} = $$        unless defined $self-&gt;{+_PID};
        $self-&gt;{+_TID} = get_tid() unless defined $self-&gt;{+_TID};

        # This is for https://github.com/Test-More/test-more/issues/16
        # and https://rt.perl.org/Public/Bug/Display.html?id=127774
        # END blocks run in reverse order. This insures the END block is loaded
        # as late as possible. It will not solve all cases, but it helps.
        eval "END { Test2::API::test2_set_is_end() }; 1" or die $@;

        $self-&gt;{+LOADED} = 1;
        $_-&gt;() for @{$self-&gt;{+POST_LOAD_CALLBACKS}};
    }
    return $self-&gt;{+LOADED};
}

sub add_exit_callback {
    my $self = shift;
    my ($code) = @_;
    my $rtype = reftype($code) || "";

    confess "End callbacks must be coderefs"
        unless $code &amp;&amp; $rtype eq 'CODE';

    push @{$self-&gt;{+EXIT_CALLBACKS}} =&gt; $code;
}

sub ipc_disable {
    my $self = shift;

    confess "Attempt to disable IPC after it has been initialized"
        if $self-&gt;{+IPC};

    $self-&gt;{+IPC_DISABLED} = 1;
}

sub add_ipc_driver {
    my $self = shift;
    my ($driver) = @_;
    unshift @{$self-&gt;{+IPC_DRIVERS}} =&gt; $driver;

    return unless $self-&gt;{+FINALIZED};

    # Why is the @CARP_NOT entry not enough?
    local %Carp::Internal = %Carp::Internal;
    $Carp::Internal{'Test2::IPC::Driver'} = 1;

    carp "IPC driver $driver loaded too late to be used as the global ipc driver";
}

sub enable_ipc_polling {
    my $self = shift;

    $self-&gt;{+_PID} = $$        unless defined $self-&gt;{+_PID};
    $self-&gt;{+_TID} = get_tid() unless defined $self-&gt;{+_TID};

    $self-&gt;add_context_init_callback(
        # This is called every time a context is created, it needs to be fast.
        # $_[0] is a context object
        sub {
            return unless $self-&gt;{+IPC_POLLING};
            return unless $self-&gt;{+IPC};
            return unless $self-&gt;{+IPC}-&gt;pending();
            return $_[0]-&gt;{hub}-&gt;cull;
        }
    ) unless defined $self-&gt;ipc_polling;

    $self-&gt;set_ipc_polling(1);
}

sub get_ipc_pending {
    my $self = shift;
    return -1 unless $self-&gt;{+IPC};
    $self-&gt;{+IPC}-&gt;pending();
}

sub _check_pid {
    my $self = shift;
    my ($pid) = @_;
    return kill(0, $pid);
}

sub set_ipc_pending {
    my $self = shift;
    return unless $self-&gt;{+IPC};
    my ($val) = @_;

    confess "value is required for set_ipc_pending"
        unless $val;

    $self-&gt;{+IPC}-&gt;set_pending($val);
}

sub disable_ipc_polling {
    my $self = shift;
    return unless defined $self-&gt;{+IPC_POLLING};
    $self-&gt;{+IPC_POLLING} = 0;
}

sub _ipc_wait {
    my ($timeout) = @_;
    my $fail = 0;

    $timeout = DEFAULT_IPC_TIMEOUT() unless defined $timeout;

    my $ok = eval {
        if (CAN_FORK) {
            local $SIG{ALRM} = sub { die "Timeout waiting on child processes" };
            alarm $timeout;

            while (1) {
                my $pid = CORE::wait();
                my $err = $?;
                last if $pid == -1;
                next unless $err;
                $fail++;

                my $sig = $err &amp; 127;
                my $exit = $err &gt;&gt; 8;
                warn "Process $pid did not exit cleanly (wstat: $err, exit: $exit, sig: $sig)\n";
            }

            alarm 0;
        }

        if (USE_THREADS) {
            my $start = time;

            while (1) {
                last unless threads-&gt;list();
                die "Timeout waiting on child thread" if time - $start &gt;= $timeout;
                sleep 1;
                for my $t (threads-&gt;list) {
                    # threads older than 1.34 do not have this :-(
                    next if $t-&gt;can('is_joinable') &amp;&amp; !$t-&gt;is_joinable;
                    $t-&gt;join;
                    # In older threads we cannot check if a thread had an error unless
                    # we control it and its return.
                    my $err = $t-&gt;can('error') ? $t-&gt;error : undef;
                    next unless $err;
                    my $tid = $t-&gt;tid();
                    $fail++;
                    chomp($err);
                    warn "Thread $tid did not end cleanly: $err\n";
                }
            }
        }

        1;
    };
    my $error = $@;

    return 0 if $ok &amp;&amp; !$fail;
    warn $error unless $ok;
    return 255;
}

sub set_exit {
    my $self = shift;

    return if $self-&gt;{+PRELOAD};

    my $exit     = $?;
    my $new_exit = $exit;

    if ($INC{'Test/Builder.pm'} &amp;&amp; $Test::Builder::VERSION ne $Test2::API::VERSION) {
        print STDERR &lt;&lt;"        EOT";

********************************************************************************
*                                                                              *
*            Test::Builder -- Test2::API version mismatch detected             *
*                                                                              *
********************************************************************************
   Test2::API Version: $Test2::API::VERSION
Test::Builder Version: $Test::Builder::VERSION

This is not a supported configuration, you will have problems.

        EOT
    }

    for my $ctx (values %{$self-&gt;{+CONTEXTS}}) {
        next unless $ctx;

        next if $ctx-&gt;_aborted &amp;&amp; ${$ctx-&gt;_aborted};

        # Only worry about contexts in this PID
        my $trace = $ctx-&gt;trace || next;
        next unless $trace-&gt;pid &amp;&amp; $trace-&gt;pid == $$;

        # Do not worry about contexts that have no hub
        my $hub = $ctx-&gt;hub  || next;

        # Do not worry if the state came to a sudden end.
        next if $hub-&gt;bailed_out;
        next if defined $hub-&gt;skip_reason;

        # now we worry
        $trace-&gt;alert("context object was never released! This means a testing tool is behaving very badly");

        $exit     = 255;
        $new_exit = 255;
    }

    if (!defined($self-&gt;{+_PID}) or !defined($self-&gt;{+_TID}) or $self-&gt;{+_PID} != $$ or $self-&gt;{+_TID} != get_tid()) {
        $? = $exit;
        return;
    }

    my @hubs = $self-&gt;{+STACK} ? $self-&gt;{+STACK}-&gt;all : ();

    if (@hubs and $self-&gt;{+IPC} and !$self-&gt;{+NO_WAIT}) {
        local $?;
        my %seen;
        for my $hub (reverse @hubs) {
            my $ipc = $hub-&gt;ipc or next;
            next if $seen{$ipc}++;
            $ipc-&gt;waiting();
        }

        my $ipc_exit = _ipc_wait($self-&gt;{+IPC_TIMEOUT});
        $new_exit ||= $ipc_exit;
    }

    # None of this is necessary if we never got a root hub
    if(my $root = shift @hubs) {
        my $trace = Test2::EventFacet::Trace-&gt;new(
            frame  =&gt; [__PACKAGE__, __FILE__, 0, __PACKAGE__ . '::END'],
            detail =&gt; __PACKAGE__ . ' END Block finalization',
        );
        my $ctx = Test2::API::Context-&gt;new(
            trace =&gt; $trace,
            hub   =&gt; $root,
        );

        if (@hubs) {
            $ctx-&gt;diag("Test ended with extra hubs on the stack!");
            $new_exit  = 255;
        }

        unless ($root-&gt;no_ending) {
            local $?;
            $root-&gt;finalize($trace) unless $root-&gt;ended;
            $_-&gt;($ctx, $exit, \$new_exit) for @{$self-&gt;{+EXIT_CALLBACKS}};
            $new_exit ||= $root-&gt;failed;
            $new_exit ||= 255 unless $root-&gt;is_passing;
        }
    }

    $new_exit = 255 if $new_exit &gt; 255;

    if ($new_exit &amp;&amp; eval { require Test2::API::Breakage; 1 }) {
        my @warn = Test2::API::Breakage-&gt;report();

        if (@warn) {
            print STDERR "\nYou have loaded versions of test modules known to have problems with Test2.\nThis could explain some test failures.\n";
            print STDERR "$_\n" for @warn;
            print STDERR "\n";
        }
    }

    $? = $new_exit;
}

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Test2::API::Instance - Object used by Test2::API under the hood

=head1 DESCRIPTION

This object encapsulates the global shared state tracked by
L&lt;Test2&gt;. A single global instance of this package is stored (and
obscured) by the L&lt;Test2::API&gt; package.

There is no reason to directly use this package. This package is documented for
completeness. This package can change, or go away completely at any time.
Directly using, or monkeypatching this package is not supported in any way
shape or form.

=head1 SYNOPSIS

    use Test2::API::Instance;

    my $obj = Test2::API::Instance-&gt;new;

=over 4

=item $pid = $obj-&gt;pid

PID of this instance.

=item $obj-&gt;tid

Thread ID of this instance.

=item $obj-&gt;reset()

Reset the object to defaults.

=item $obj-&gt;load()

Set the internal state to loaded, and run and stored post-load callbacks.

=item $bool = $obj-&gt;loaded

Check if the state is set to loaded.

=item $arrayref = $obj-&gt;post_load_callbacks

Get the post-load callbacks.

=item $obj-&gt;add_post_load_callback(sub { ... })

Add a post-load callback. If C&lt;load()&gt; has already been called then the callback will
be immediately executed. If C&lt;load()&gt; has not been called then the callback will be
stored and executed later when C&lt;load()&gt; is called.

=item $hashref = $obj-&gt;contexts()

Get a hashref of all active contexts keyed by hub id.

=item $arrayref = $obj-&gt;context_acquire_callbacks

Get all context acquire callbacks.

=item $arrayref = $obj-&gt;context_init_callbacks

Get all context init callbacks.

=item $arrayref = $obj-&gt;context_release_callbacks

Get all context release callbacks.

=item $arrayref = $obj-&gt;pre_subtest_callbacks

Get all pre-subtest callbacks.

=item $obj-&gt;add_context_init_callback(sub { ... })

Add a context init callback. Subs are called every time a context is created. Subs
get the newly created context as their only argument.

=item $obj-&gt;add_context_release_callback(sub { ... })

Add a context release callback. Subs are called every time a context is released. Subs
get the released context as their only argument. These callbacks should not
call release on the context.

=item $obj-&gt;add_pre_subtest_callback(sub { ... })

Add a pre-subtest callback. Subs are called every time a subtest is
going to be run. Subs get the subtest name, coderef, and any
arguments.

=item $obj-&gt;set_exit()

This is intended to be called in an C&lt;END { ... }&gt; block. This will look at
test state and set $?. This will also call any end callbacks, and wait on child
processes/threads.

=item $obj-&gt;set_ipc_pending($val)

Tell other processes and threads there is a pending event. C&lt;$val&gt; should be a
unique value no other thread/process will generate.

B&lt;Note:&gt; This will also make the current process see a pending event.

=item $pending = $obj-&gt;get_ipc_pending()

This returns -1 if it is not possible to know.

This returns 0 if there are no pending events.

This returns 1 if there are pending events.

=item $timeout = $obj-&gt;ipc_timeout;

=item $obj-&gt;set_ipc_timeout($timeout);

How long to wait for child processes and threads before aborting.

=item $drivers = $obj-&gt;ipc_drivers

Get the list of IPC drivers.

=item $obj-&gt;add_ipc_driver($DRIVER_CLASS)

Add an IPC driver to the list. The most recently added IPC driver will become
the global one during initialization. If a driver is added after initialization
has occurred a warning will be generated:

    "IPC driver $driver loaded too late to be used as the global ipc driver"

=item $bool = $obj-&gt;ipc_polling

Check if polling is enabled.

=item $obj-&gt;enable_ipc_polling

Turn on polling. This will cull events from other processes and threads every
time a context is created.

=item $obj-&gt;disable_ipc_polling

Turn off IPC polling.

=item $bool = $obj-&gt;no_wait

=item $bool = $obj-&gt;set_no_wait($bool)

Get/Set no_wait. This option is used to turn off process/thread waiting at exit.

=item $arrayref = $obj-&gt;exit_callbacks

Get the exit callbacks.

=item $obj-&gt;add_exit_callback(sub { ... })

Add an exit callback. This callback will be called by C&lt;set_exit()&gt;.

=item $bool = $obj-&gt;finalized

Check if the object is finalized. Finalization happens when either C&lt;ipc()&gt;,
C&lt;stack()&gt;, or C&lt;format()&gt; are called on the object. Once finalization happens
these fields are considered unchangeable (not enforced here, enforced by
L&lt;Test2&gt;).

=item $ipc = $obj-&gt;ipc

Get the one true IPC instance.

=item $obj-&gt;ipc_disable

Turn IPC off

=item $bool = $obj-&gt;ipc_disabled

Check if IPC is disabled

=item $stack = $obj-&gt;stack

Get the one true hub stack.

=item $formatter = $obj-&gt;formatter

Get the global formatter. By default this is the C&lt;'Test2::Formatter::TAP'&gt;
package. This could be any package that implements the C&lt;write()&gt; method. This
can also be an instantiated object.

=item $bool = $obj-&gt;formatter_set()

Check if a formatter has been set.

=item $obj-&gt;add_formatter($class)

=item $obj-&gt;add_formatter($obj)

Add a formatter. The most recently added formatter will become the global one
during initialization. If a formatter is added after initialization has occurred
a warning will be generated:

    "Formatter $formatter loaded too late to be used as the global formatter"

=item $obj-&gt;set_add_uuid_via(sub { ... })

=item $sub = $obj-&gt;add_uuid_via()

This allows you to provide a UUID generator. If provided UUIDs will be attached
to all events, hubs, and contexts. This is useful for storing, tracking, and
linking these objects.

The sub you provide should always return a unique identifier. Most things will
expect a proper UUID string, however nothing in Test2::API enforces this.

The sub will receive exactly 1 argument, the type of thing being tagged
'context', 'hub', or 'event'. In the future additional things may be tagged, in
which case new strings will be passed in. These are purely informative, you can
(and usually should) ignore them.

=back

=head1 SOURCE

The source code repository for Test2 can be found at
F&lt;http://github.com/Test-More/test-more/&gt;.

=head1 MAINTAINERS

=over 4

=item Chad Granum E&lt;lt&gt;exodist@cpan.orgE&lt;gt&gt;

=back

=head1 AUTHORS

=over 4

=item Chad Granum E&lt;lt&gt;exodist@cpan.orgE&lt;gt&gt;

=back

=head1 COPYRIGHT

Copyright 2020 Chad Granum E&lt;lt&gt;exodist@cpan.orgE&lt;gt&gt;.

This program is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

See F&lt;http://dev.perl.org/licenses/&gt;

=cut
</pre></body></html>